dotfiles/flake.nix

{
  description = "Home Manager configuration";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    neovim = {
      url = "github:neovim/neovim?dir=contrib";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { nixpkgs, home-manager, flake-utils, neovim, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        user = "nikos"; # change your user here
        dotfilesHome = "/home/${user}/.dotfiles"; # specify your dotfiles path
        pkgs = nixpkgs.legacyPackages.${system};
      in
      {
        packages.homeConfigurations.${user} = home-manager.lib.homeManagerConfiguration {
          inherit pkgs;

          # Specify your home configuration modules here, for example,
          # the path to your home.nix.
          modules = [
            ./home.nix

            {
              nixpkgs.overlays = [
                (final: prev: {
                  neovim = neovim.packages.${system}.neovim;
                })
              ];
            }
          ];

          extraSpecialArgs = { extra = { inherit user dotfilesHome; }; };
        };
      });
}