dotfiles/app/lib/prymn_web/live/server_live/index.ex

defmodule PrymnWeb.ServerLive.Index do
  alias Prymn.Servers

  use PrymnWeb, :live_view

  @impl true
  def mount(_params, _session, socket) do
    servers = Servers.list_servers()
    pid = self()

    for %{public_ip: public_ip} <- servers, public_ip != nil do
      :ok = Phoenix.PubSub.subscribe(Prymn.PubSub, "agent:#{public_ip}")

      Task.start_link(fn ->
        case Prymn.Agents.ensure_connection("#{public_ip}:50012") do
          :ok -> Process.send(pid, {:healthcheck, :up, public_ip}, [])
          {:error, _error} -> Process.send(pid, {:healthcheck, :down, public_ip}, [])
        end
      end)
    end

    {:ok, stream(socket, :servers, servers)}
  end

  @impl true
  def handle_params(params, _url, socket) do
    {:noreply, apply_action(socket, socket.assigns.live_action, params)}
  end

  defp apply_action(socket, :new, _params) do
    socket
    |> assign(:page_title, "New Server")
  end

  defp apply_action(socket, :index, _params) do
    socket
    |> assign(:page_title, "Listing Servers")
  end

  @impl true
  def handle_info({:connect, %Servers.Server{} = server}, socket) do
    {:noreply, stream_insert(socket, :servers, server)}
  end

  @impl true
  def handle_info({:healthcheck, status, ip}, socket) do
    server = Servers.get_server_by_ip!(ip)

    status =
      case status do
        :up -> "Connected"
        :down -> "Disconnected"
      end

    {:noreply,
     socket
     |> stream_insert(:servers, Map.put(server, :connection_status, status))}
  end

  @impl true
  def handle_event("delete", %{"id" => id}, socket) do
    server = Servers.get_server!(id)
    {:ok, _} = Servers.delete_server(server)

    {:noreply, stream_delete(socket, :servers, server)}
  end
end