dotfiles/home.nix
2023-10-23 14:36:02 +03:00

79 lines
2.2 KiB
Nix

{ config, pkgs, lib, extra, ... }:
{
home.username = "${extra.user}";
home.homeDirectory = "/home/${extra.user}";
# This value determines the Home Manager release that your configuration is
# compatible with. This helps avoid breakage when a new Home Manager release
# introduces backwards incompatible changes.
#
# You should not change this value, even if you update Home Manager. If you do
# want to update the value, then make sure to first check the Home Manager
# release notes.
home.stateVersion = "23.05"; # Please read the comment before changing.
# Home Manager is pretty good at managing dotfiles. The primary way to manage
# plain files is through 'home.file'.
xdg.configFile = {
"nvim".source = ./nvim;
"foot".source = ./foot;
};
xdg.dataFile = {
"nvim/lazy-lock.json".source =
config.lib.file.mkOutOfStoreSymlink "${extra.dotfilesHome}/lazy-lock.json";
};
# The home.packages option allows you to install Nix packages into your
# environment.
home.packages = with pkgs; [
neovim # neovim nightly
ripgrep # "rg" cli, alternative to grep, used by nvim
fd # find alternative, used by nvim
lsd # "ls" alternative
zoxide # "z" command
nil # Nix LSP
nixpkgs-fmt # Nix formatter
(nerdfonts.override { fonts = [ "JetBrainsMono" ]; }) # nerdfonts jetbrains mono
efm-langserver # Generic language server
];
fonts.fontconfig.enable = true;
programs.git = {
enable = true;
userName = "Nikos Papadakis";
userEmail = "nikos@papadakis.xyz";
signing.key = "78871F9905ADFF02";
signing.signByDefault = true;
includes = [
{
contents = {
init.defaultBranch = "main";
pull.rebase = true;
};
}
];
};
programs.fish = {
enable = true;
shellInit = lib.strings.concatStringsSep "\n" ([
(builtins.readFile ./fish/config.fish)
] ++ lib.attrsets.mapAttrsToList
(
name: value: builtins.readFile (./fish/functions + ("/" + name))
)
(builtins.readDir ./fish/functions)
);
};
programs.direnv = {
enable = true;
nix-direnv.enable = true;
};
# Let Home Manager install and manage itself.
programs.home-manager.enable = true;
}