{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
    systems.url = "github:nix-systems/default";
    devenv.url = "github:cachix/devenv";
  };

  nixConfig = {
    extra-trusted-public-keys = "devenv.cachix.org-1:w1cLUi8dv3hnoSPGAuibQv+f9TZLr6cv/Hm9XgU50cw=";
    extra-substituters = "https://devenv.cachix.org";
  };

  outputs = { self, nixpkgs, devenv, systems, ... } @ inputs:
    let
      forEachSystem = nixpkgs.lib.genAttrs (import systems);
    in
    {
      packages = forEachSystem (system: {
        devenv-up = self.devShells.${system}.default.config.procfileScript;
      });

      devShells = forEachSystem
        (system:
          let
            pkgs = nixpkgs.legacyPackages.${system};
            config = self.devShells.${system}.default.config;
          in
          {
            default = devenv.lib.mkShell {
              inherit inputs pkgs;
              modules = [
                {
                  packages = [ pkgs.wp-cli ];

                  languages.php = {
                    enable = true;
                    fpm.pools.wp = {
                      settings = {
                        "pm" = "dynamic";
                        "pm.max_children" = 75;
                        "pm.start_servers" = 10;
                        "pm.min_spare_servers" = 5;
                        "pm.max_spare_servers" = 20;
                        "pm.max_requests" = 500;
                      };
                    };
                  };

                  services.mysql = {
                    enable = true;
                    package = pkgs.mariadb_110;
                    ensureUsers = [
                      {
                        name = "wordpress";
                        password = "wordpress";
                        ensurePermissions = { "wordpress.*" = "ALL PRIVILEGES"; };
                      }
                    ];
                    initialDatabases = [{ name = "wordpress"; }];
                  };

                  services.caddy = {
                    enable = true;
                    package = pkgs.caddy;
                    virtualHosts."localhost:8000" = {
                      extraConfig = ''
                        root * ${config.env.DEVENV_ROOT}/core
                        php_fastcgi unix/${config.languages.php.fpm.pools.wp.socket}
                        file_server
                        tls internal {
                          on_demand
                        }
                      '';
                    };
                  };

                  scripts.caddy_permissions.exec = ''
                    sudo setcap cap_net_bind_service=+ep ${pkgs.caddy}/bin/caddy || exit 1
                    printf "If Caddy created the CA succesfuly, install it on your OS.\n"
                    printf "Debian:\n"
                    printf "  sudo cp .devenv/state/caddy/data/caddy/pki/authorities/local/root.crt /usr/local/share/ca-certificates/root.crt\n"
                    printf "  sudo update-ca-certificates\n\n"
                    printf "Archlinux:\n"
                    printf "  sudo cp .devenv/state/caddy/data/caddy/pki/authorities/local/root.crt /etc/ca-certificates/trust-source/anchors/root.crt\n"
                    printf "  sudo update-ca-certificates\n"
                  '';

                  # scripts.install_wp.exec = ''
                  #   set -e
                  #   if ! [ -d ./data ]; then
                  #     wp core download --path=data
                  #     wp config create --path=data --dbname=wp --dbuser=dev --dbhost=127.0.0.1
                  #     wp db create --path=data --defaults
                  #     wp core install --path=data --url=localhost --title=WordPressDev --admin_user=admin --admin_password=admin --admin_email=admin@wp.local
                  #   else
                  #     echo "WordPress already installed. To force re-install remove the data directory"
                  #   fi
                  # '';
                }
              ];
            };
          });
    };
}